Bwr102 gebruikers

[esschenk]

Hallo,
Heb net mijn oregon bwr102 binnen gekregen
voor een spotprijs 43,- incl verzend (vandaagleven.nl)
werkt goed rfxcom ziet hem prima .
mijn vraag is hoe herkend homeseer de 4 gebruikers
in de rfxcom.ini heb ik 4 gebruikers aangemaakt
[Weight]
Person1=Ed
Min1=90
Max1=110
Length1=175

is het zo dat hij kijk naar het gewicht wat valt tussen min1 en max1
en stored dan deze waarde bij deze gebruiker!!!

het is mij niet helemaal duidelijk ik kan hier ook niet veel van vinden in de rfxcom handleiding

kan iemand mij dit uitleggen

groet ed

CM11A,DooNetwork,ActiveBackup Plugin,NetCAM,PowerTrigger,RFXCOM,CheaperRfid,BLebaymonitor

[RdP]

Klopt precies zoals je het beschijft werkt het inderdaad !!!

/RdP

[TANE]

Als je Rfxcharts installeert krijg je wat beter overzicht + de mogelijkheid om de waardes online te veranderen via HS zelf.

http://www.jphuddlestone.co.uk/rfxcharts/rfxcharts1.htm

[esschenk]

Hoi,
Ik had al zo'n vermoeden dat het zo werkte
rfxchart had ik nog een oude versie van deze vervangen door de nieuwste versie.
het duurt alleen een aantal dagen voor je de charts goed krijgt
maar werkt verder goed nu.
alleen zou ik het liefste staafdiagrammen zien ipv
een curve.
ik weet niet of dit in te stellen is !!!

ed

CM11A,DooNetwork,ActiveBackup Plugin,NetCAM,PowerTrigger,RFXCOM,CheaperRfid,BLebaymonitor

[esschenk]

Hallo,

Is het mogelijk om virtual devices aan te maken voor de
gebruikers van de weegschaal.
ik kan nu op mijn website alleen de laatste meting laten zien
en ik wil dit graag voor alle 4 de gebruikers
en/of heeft iemand dit al werkend

ed

CM11A,DooNetwork,ActiveBackup Plugin,NetCAM,PowerTrigger,RFXCOM,CheaperRfid,BLebaymonitor

[b_weijenberg]

Ed, probeer dit eens: (ik heb dit nog niet getest)

Maak in de ini file voor elk persoon een Vdevicex=<device code> aan (x=1 tot 4) waarin je de device code opneemt.
Voorbeeld:
[Weight]
Person1=Ed
Min1=90
Max1=100
Length1=185
Vdevice1=A1

Code: Select all

' writes body weight monitor readings into the RFXCOM database
' this program only works when the weights of the different persons don't overlap.
' add values for up to 4 persons defined in the hspi_RFXCOM.INI file
' [Weight]
' Person1=    enter the name of the person
' Min1=75     enter the minimum weight in kg or lb for this person to determine if the measured weight belongs to person1
' Max1=85     enter the maximum weight in kg or lb for this person to determine if the measured weight belongs to person1
' Length1=175 enter the length in cm or inch for this person (enter a value below 10 if no BMI to calculate)
' Vdevice1=A1  enter the device code

Const INI_FILE As String = "hspi_RFXCOM.ini"
Const DefaultPath = "C:\Program Files\HomeSeer 2\data\RFXCOM\RFXCOM.mdb"

Const swversion = "0.6" ' the version of this file
'version 0.1
'   initial version
'version 0.2
'   error due to wrong variable
'version 0.3
'   database path changed to data\RFXCOM
'version 0.4
'   metric or English selected depending on ini setting
'version 0.5
'   speak weight added.
'version 0.6
'   display values in a virtual device added.

Sub Main(Optional ByVal pParms As String = "")
    Dim dvref As Long
    Dim dv As Object
    Dim strHC As String

    Dim strDatabase As String
    Dim strConnectionString As String
    Dim sql As String
    Dim objConn As Object
    Dim bValidPerson As Boolean = False
    Dim i As Integer

    Dim strPerson As String
    Dim intMin As Integer
    Dim intMax As Integer
    Dim sngBMI As Single
    Dim sngWeight As Single = 0
    Dim sngLength As Single
    Dim strUnit As String
    Dim strVdevice As String

    If hs.GetINISetting("Startup", "Metric", "1", INI_FILE) = "1" Then
        strUnit = "kg"
    Else
        strUnit = "lb"
    End If

    hs.WriteLog("Info", "RFXWeight.vb Version " & swversion & " triggered.")

    strHC = hs.GetINISetting("Startup", "InpDevHC", "", INI_FILE)
    For i = 1 To 99
        dvref = hs.GetDeviceRef(strHC & i.ToString)
        If dvref <> -1 Then
            dv = hs.GetDeviceByRef(dvref)
            If left(dv.iomisc, 6) = "WEIGHT" Then
                sngWeight = hs.DeviceValue(dv.hc & dv.dc) / 10
            End If
        End If
    Next i

    If sngWeight <> 0 Then
        For i = 1 To 4
            strPerson = hs.GetINISetting("Weight", "Person" & i.ToString, "", INI_FILE)
            intMin = hs.GetINISetting("Weight", "Min" & i.ToString, "1", INI_FILE)
            intMax = hs.GetINISetting("Weight", "Max" & i.ToString, "1", INI_FILE)
            sngLength = hs.GetINISetting("Weight", "Length" & i.ToString, "1", INI_FILE)
            If strPerson <> "" And sngWeight >= intMin And sngWeight <= intMax Then
                bValidPerson = True
                strVdevice = Trim(hs.GetINISetting("Weight", "VDevice" & i.ToString, "", INI_FILE))
                Exit For
            End If
        Next i

        If bValidPerson Then
            If sngLength > 10 Then
                If strUnit = "kg" Then
                    sngLength = sngLength / 100
                    sngBMI = math.round((sngWeight / (sngLength * sngLength)), 1)
                Else
                    sngBMI = math.round(((sngWeight * 703) / (sngLength * sngLength)), 1)
                End If
            Else
                sngBMI = 0
            End If
            If strVdevice <> "" Then
                hs.SetDeviceValue(strVdevice, Clng(sngWeight * 10))
                hs.SetDeviceString(strVdevice, sngWeight.ToString & strUnit & " / BMI:" & sngBMI.ToString)
            End If
            strDatabase = hs.GetINISetting("RFXDatabase", "Path", DefaultPath, INI_FILE)
            objConn = CreateObject("ADODB.Connection")
            strConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & strDatabase
            objConn.Open(strConnectionString)
            sql = "insert into Weight (rfxdate, rfxtime, weight, BMI, person) values ('" & DateValue(Now()) & "','" & TimeValue(Now()) & "','" & sngWeight & "','" & sngBMI & "','" & strPerson & "')"
            objConn.execute(sql)
            objConn.close()
            objConn = Nothing
            hs.WriteLog("info", "RFXWeight weight " & sngWeight.ToString & strUnit & " and BMI=" & sngBMI.ToString & " stored for person: " & strPerson)
            hs.speak(strPerson & "'s weight is " & sngWeight.ToString & strUnit)
        Else
            hs.WriteLog("info", "Warning: RFXWeight weight " & sngWeight.ToString & strUnit & " not stored for any person!!!!!")
            hs.speak("Unknown person weight is " & sngWeight.ToString & strUnit)
        End If
    Else
        hs.WriteLog("info", "Warning: RFXWeight weight value zero.")
    End If

End Sub

Bert

[esschenk]

hallo bert,

ik heb de hspi_rfxcom.ini aangepast zie voorbeeld

[Weight]
Person1=Ed
Min1=95
Max1=110
Length1=180
Vdevice=W1

Person2=Elly
Min2=80
Max2=88
Length2=166
Vdevice=W2

maar het lijkt niet te werken

of ben ik iets vergeten

thanks
ed

CM11A,DooNetwork,ActiveBackup Plugin,NetCAM,PowerTrigger,RFXCOM,CheaperRfid,BLebaymonitor

[Digit]

Misschien een overbodige tip, maar als je van elke gebruiker de laatst opgeslagen waarde kunt ophalen, kun je selecteren op gewichtsmarge. Als je bv. 2 kids hebt die elkaar maar weinig in gewicht schelen zou dat beter werken denk ik.

[Bwired]

Yep doe ik ook, laatste records ophalen (alle personen), mag X procent afwijken. indien je het dan niet kan bepalen is het de kat of de werkster [:D]

[b_weijenberg]

Ed,

2 fouten in mijn bericht:
Bij Vdevice moet 1 en 2 toegevoegd worden
[Weight]
Person1=Ed
Min1=95
Max1=110
Length1=180
Vdevice1=W1

Person2=Elly
Min2=80
Max2=88
Length2=166
Vdevice2=W2


En in deze regel Lng door Clng vervangen:
hs.SetDeviceValue(strVdevice, Clng(sngWeight * 10))

Dat krijg je als je iets ongetest plaatst

Ik heb mijn oorspronkelijke bericht aangepast.

[esschenk]

Hallo Bert,

1 foutje had ik ook gevonden maar met de virtueel user 1tot 4
werkt het nu perfect.
dit is precies wat ik wilde.

bedankt voor het script

ed

CM11A,DooNetwork,ActiveBackup Plugin,NetCAM,PowerTrigger,RFXCOM,CheaperRfid,BLebaymonitor

[Hetwieg]

Offtopic: Mischien leuk om gewicht van kat op internet er bij te zetten

Waarom zelf het wiel nog een keer uitvinden.