Page 1 of 5

Afvalwijzer script

PostPosted: Tue Aug 11, 2015 9:20 am
by raymonvdm
Ik had laatst het idee om de afvalwijzer weer te geven in HSTouch, is er iemand die dit al heeft gedaan en het script wil delen.

http://mijnafvalwijzer.nl/

De android app maakt gebruik van een JSON url om de data op te halen. En ik wil eigenlijk een tijd en datum weergeven waarop de volgende afval actie is.

http://json.mijnafvalwijzer.nl//?method ... plaatsnaam

En deze komt terug met de volgende data

Code: Select all
{"afvalDate":"1420122044","contentDate":"1436366653","iconsDate":"1429778402"}


Maar met de epoch converter kan ik daar niets mee dus volgens mij ontbreekt er informatie?

Re: afvalwijzer script

PostPosted: Tue Aug 11, 2015 10:37 am
by bartbakels
Raymond,

Strak plan, ik ga eens kijken of ik hier iets mee kan. ik heb zoiets ook geprobeert te implementeren door de standaard triggers van hs3 te gebruiken echter krijg het niet ingericht zoals ik wil. Wellicht kunnen we hier iets mee.

MVG

Bart

Re: afvalwijzer script

PostPosted: Tue Aug 11, 2015 10:50 am
by bartbakels
Raymond,

Ik krijg alleen maar NOKtjes, waarschijnlijk gaat er iets mis in de JSon request die ik stuur.

overigens heb de developer gevonden;

https://www.elance.com/s/daveloper/

mvg'

Bart

Re: afvalwijzer script

PostPosted: Tue Aug 11, 2015 10:53 am
by raymonvdm
Ik kom niet verder dan de link openen in de browser, wat ik verder moet doen begrijp ik allemaal niet :-)

Re: afvalwijzer script

PostPosted: Tue Aug 11, 2015 11:54 am
by stefxx
Dat is toch gewoon datum/tijd sinds 1/1/1970? In Excel: =<nummer>/(60*60*24)+"1/1/1970"

Dan komt dit eruit:
1420122044 1-01-15 14:20
1436366653 8-07-15 14:44
1429778402 23-04-15 8:40

Overigens krijg ik ook alleen maar NOKjes op het request. Mijn adres is vast niet ondersteund ofzo...

Re: afvalwijzer script

PostPosted: Tue Aug 11, 2015 12:15 pm
by raymonvdm
Ik gebruikte deze converter http://www.epochconverter.com/

Re: afvalwijzer script

PostPosted: Tue Aug 11, 2015 12:19 pm
by stefxx
Doet idd hetzelfde. Maar wat is dan de vraag?

Re: afvalwijzer script

PostPosted: Tue Aug 11, 2015 12:34 pm
by raymonvdm
stefxx wrote:Doet idd hetzelfde. Maar wat is dan de vraag?


Nou het echt antwoord in de app is dat vandaag plastic en metaal opgehaald zou worden maar dat zag ik niet terug in het JSON antwoord

Re: afvalwijzer script

PostPosted: Tue Aug 11, 2015 1:32 pm
by stefxx
Yup. Ik heb geen Android, maar een Windows Phone. Als ik die proxy naar mijn PC en fiddler laat kijken wat er gebeurd zie ik inderdaad iets vergelijkbaars (adres is verzonnen, mijn eigen adres wordt niet ondersteund):

www.mijnafvalwijzer.nl/json/?method=get ... version=13 HTTP/1.1

Wat ik ook doe, ik krijg een NOK terug. Als ik "toev" verander in "toevoeging" krijg ik wel iets terug. Als ik getversion verander in getversionV2 krijg ik hetzelfde als in jouw eerste post.

Maar het probleem is dat de windows app daarna crashed. Pas als ik de proxy weer verwijder loopt hij door. Dus ik denk dat ik niet alles kan zien...

Re: afvalwijzer script

PostPosted: Tue Aug 11, 2015 1:41 pm
by stefxx
Ah, gevonden:

http://json.mijnafvalwijzer.nl/?method= ... 20HTTP/1.1

Schrik niet van de enorme hoeveelheid data die je terugkrijgt :D :D

Re: afvalwijzer script

PostPosted: Tue Aug 11, 2015 1:47 pm
by stefxx
Hier de output, beetje leesbaar: http://codebeautify.org/jsonviewer/c0531e

En als je de iconen zoekt: http://codebeautify.org/jsonviewer/1f58e2

Re: afvalwijzer script

PostPosted: Tue Aug 11, 2015 1:57 pm
by raymonvdm
Op een of andere manier krijg ik op mijn eigen adres ook een NOK terug, terwijl ik de bazin nooit hoor klagen dat het niet werkt. Ik moet nog eens kijken welke url ik precies moet hebben en stiekem hoop ik dat iemand dan een script kan maken wat "normale" HS3 gebruikers kunnen gebruiken om slechts enkele gegevens in een virtual device te plaatsen. Het virtual device kan dan weer gebruikt worden in HSTouch

Re: afvalwijzer script

PostPosted: Tue Aug 11, 2015 2:05 pm
by stefxx
Vergeet die getversion method. Die doet niks (zinnigs) en geeft meestal een NOK. Je moet de postcodecheck method hebben (zie hierboven). Daar staat alles in.

Een script om daaruit te halen wat je zoekt kan ik je niet mee helpen, geen tijd... ik zou zeggen, google eens rond hoe je een JSON call kan interpreteren.

Re: afvalwijzer script

PostPosted: Tue Aug 11, 2015 3:42 pm
by stefxx
Hier een begin van een script. Doet nog niks met Homeseer maar haalt in ieder geval de data uit de JSON tekst. Met minimale script vaardigheden moet je hier iets van kunnen maken. Sla onderstaand op als een .vbs script en runnen maar...

Meeste is trouwens geleend van het Internet, en gemaakt door Gerrit van Kuipers.

Code: Select all
Dim Postcode, Huisnummer, Toevoeging
Dim objHttp, Text, i, Ophaaldagen

' Vul hier je eigen gegevens in
Postcode = "3514ax"
Huisnummer = "11"
Toevoeging = "b"

' Ander test adres
'Postcode = "8266bh"
'Huisnummer = "1"
'Toevoeging = ""

Set objHttp = CreateObject("Msxml2.ServerXMLHTTP")
objHttp.Open "GET", "http://json.mijnafvalwijzer.nl/?method=postcodecheck&postcode=" & Postcode & "&street=&huisnummer=" & Huisnummer & "&toevoeging=" & Toevoeging & _
    "&platform=phone&langs=nl&mobiletype=android&platform=phone&version=33%20HTTP/1.1", False
objHttp.Send
Text = objHttp.ResponseText
Set objHttp = Nothing

If Len(Text) > 10 Then

    Set oJSON = New aspJSON
    oJSON.loadJSON(Text)

    'Get single value
    WScript.echo "Response: " & oJSON.data("response")
    WScript.echo "Gemeente: " & oJSON.data("data")("gemeente")
    Ophaaldagen = ""
    For Each i In oJSON.data("data")("ophaaldagen")("data")
        Set this = oJSON.data("data")("ophaaldagen")("data").item(i)
        Ophaaldagen = Ophaaldagen & _
        this.item("type") & ": " & this.item("date") & chr(13)
    Next
    WScript.echo "Ophaaldagen: " & chr(13) & Ophaaldagen

Else   

    WScript.echo "No data received. Location probably not supported by mijnafvalwijzer.nl."
   
End If

'Februari 2014 - Version 1.17 by Gerrit van Kuipers
Class aspJSON
   Public data
   Private p_JSONstring
   private aj_in_string, aj_in_escape, aj_i_tmp, aj_char_tmp, aj_s_tmp, aj_line_tmp, aj_line, aj_lines, aj_currentlevel, aj_currentkey, aj_currentvalue, aj_newlabel, aj_XmlHttp, aj_RegExp, aj_colonfound

   Private Sub Class_Initialize()
      Set data = Collection()

       Set aj_RegExp = new regexp
       aj_RegExp.Pattern = "\s{0,}(\S{1}[\s,\S]*\S{1})\s{0,}"
       aj_RegExp.Global = False
       aj_RegExp.IgnoreCase = True
       aj_RegExp.Multiline = True
   End Sub

   Private Sub Class_Terminate()
      Set data = Nothing
       Set aj_RegExp = Nothing
   End Sub

   Public Sub loadJSON(inputsource)
      inputsource = aj_MultilineTrim(inputsource)
      If Len(inputsource) = 0 Then Err.Raise 1, "loadJSON Error", "No data to load."
      
      select case Left(inputsource, 1)
         case "{", "["
         case else
            Set aj_XmlHttp = WScript.CreateObject("Msxml2.ServerXMLHTTP")
            aj_XmlHttp.open "GET", inputsource, False
            aj_XmlHttp.setRequestHeader "Content-Type", "text/json"
            aj_XmlHttp.setRequestHeader "CharSet", "UTF-8"
            aj_XmlHttp.Send
            inputsource = aj_XmlHttp.responseText
            set aj_XmlHttp = Nothing
      end select

      p_JSONstring = CleanUpJSONstring(inputsource)
      aj_lines = Split(p_JSONstring, Chr(13) & Chr(10))

      Dim level(99)
      aj_currentlevel = 1
      Set level(aj_currentlevel) = data
      For Each aj_line In aj_lines
         aj_currentkey = ""
         aj_currentvalue = ""
         If Instr(aj_line, ":") > 0 Then
            aj_in_string = False
            aj_in_escape = False
            aj_colonfound = False
            For aj_i_tmp = 1 To Len(aj_line)
               If aj_in_escape Then
                  aj_in_escape = False
               Else
                  Select Case Mid(aj_line, aj_i_tmp, 1)
                     Case """"
                        aj_in_string = Not aj_in_string
                     Case ":"
                        If Not aj_in_escape And Not aj_in_string Then
                           aj_currentkey = Left(aj_line, aj_i_tmp - 1)
                           aj_currentvalue = Mid(aj_line, aj_i_tmp + 1)
                           aj_colonfound = True
                           Exit For
                        End If
                     Case "\"
                        aj_in_escape = True
                  End Select
               End If
            Next
            if aj_colonfound then
               aj_currentkey = aj_Strip(aj_JSONDecode(aj_currentkey), """")
               If Not level(aj_currentlevel).exists(aj_currentkey) Then level(aj_currentlevel).Add aj_currentkey, ""
            end if
         End If
         If right(aj_line,1) = "{" Or right(aj_line,1) = "[" Then
            If Len(aj_currentkey) = 0 Then aj_currentkey = level(aj_currentlevel).Count
            Set level(aj_currentlevel).Item(aj_currentkey) = Collection()
            Set level(aj_currentlevel + 1) = level(aj_currentlevel).Item(aj_currentkey)
            aj_currentlevel = aj_currentlevel + 1
            aj_currentkey = ""
         ElseIf right(aj_line,1) = "}" Or right(aj_line,1) = "]" or right(aj_line,2) = "}," Or right(aj_line,2) = "]," Then
            aj_currentlevel = aj_currentlevel - 1
         ElseIf Len(Trim(aj_line)) > 0 Then
            if Len(aj_currentvalue) = 0 Then aj_currentvalue = aj_line
            aj_currentvalue = getJSONValue(aj_currentvalue)

            If Len(aj_currentkey) = 0 Then aj_currentkey = level(aj_currentlevel).Count
            level(aj_currentlevel).Item(aj_currentkey) = aj_currentvalue
         End If
      Next
   End Sub

   Public Function Collection()
      set Collection = WScript.CreateObject("Scripting.Dictionary")
   End Function

   Public Function AddToCollection(dictobj)
      if TypeName(dictobj) <> "Dictionary" then Err.Raise 1, "AddToCollection Error", "Not a collection."
      aj_newlabel = dictobj.Count
      dictobj.Add aj_newlabel, Collection()
      set AddToCollection = dictobj.item(aj_newlabel)
   end function

   Private Function CleanUpJSONstring(aj_originalstring)
      aj_originalstring = Replace(aj_originalstring, Chr(13) & Chr(10), "")
      aj_originalstring = Mid(aj_originalstring, 2, Len(aj_originalstring) - 2)
      aj_in_string = False : aj_in_escape = False : aj_s_tmp = ""
      For aj_i_tmp = 1 To Len(aj_originalstring)
         aj_char_tmp = Mid(aj_originalstring, aj_i_tmp, 1)
         If aj_in_escape Then
            aj_in_escape = False
            aj_s_tmp = aj_s_tmp & aj_char_tmp
         Else
            Select Case aj_char_tmp
               Case "\" : aj_s_tmp = aj_s_tmp & aj_char_tmp : aj_in_escape = True
               Case """" : aj_s_tmp = aj_s_tmp & aj_char_tmp : aj_in_string = Not aj_in_string
               Case "{", "["
                  aj_s_tmp = aj_s_tmp & aj_char_tmp & aj_InlineIf(aj_in_string, "", Chr(13) & Chr(10))
               Case "}", "]"
                  aj_s_tmp = aj_s_tmp & aj_InlineIf(aj_in_string, "", Chr(13) & Chr(10)) & aj_char_tmp
               Case "," : aj_s_tmp = aj_s_tmp & aj_char_tmp & aj_InlineIf(aj_in_string, "", Chr(13) & Chr(10))
               Case Else : aj_s_tmp = aj_s_tmp & aj_char_tmp
            End Select
         End If
      Next

      CleanUpJSONstring = ""
      aj_s_tmp = split(aj_s_tmp, Chr(13) & Chr(10))
      For Each aj_line_tmp In aj_s_tmp
         aj_line_tmp = replace(replace(aj_line_tmp, chr(10), ""), chr(13), "")
         CleanUpJSONstring = CleanUpJSONstring & aj_Trim(aj_line_tmp) & Chr(13) & Chr(10)
      Next
   End Function

   Private Function getJSONValue(ByVal val)
      val = Trim(val)
      If Left(val,1) = ":"  Then val = Mid(val, 2)
      If Right(val,1) = "," Then val = Left(val, Len(val) - 1)
      val = Trim(val)

      Select Case val
         Case "true"  : getJSONValue = True
         Case "false" : getJSONValue = False
         Case "null" : getJSONValue = Null
         Case Else
            If (Instr(val, """") = 0) Then
               If IsNumeric(val) Then
                  getJSONValue = CDbl(val)
               Else
                  getJSONValue = val
               End If
            Else
               If Left(val,1) = """" Then val = Mid(val, 2)
               If Right(val,1) = """" Then val = Left(val, Len(val) - 1)
               getJSONValue = aj_JSONDecode(Trim(val))
            End If
      End Select
   End Function

   Private JSONoutput_level
   Public Function JSONoutput()
      dim wrap_dicttype, aj_label
      JSONoutput_level = 1
      wrap_dicttype = "[]"
      For Each aj_label In data
          If Not aj_IsInt(aj_label) Then wrap_dicttype = "{}"
      Next
      JSONoutput = Left(wrap_dicttype, 1) & Chr(13) & Chr(10) & GetDict(data) & Right(wrap_dicttype, 1)
   End Function

   Private Function GetDict(objDict)
      dim aj_item, aj_keyvals, aj_label, aj_dicttype
      For Each aj_item In objDict
         Select Case TypeName(objDict.Item(aj_item))
            Case "Dictionary"
               GetDict = GetDict & Space(JSONoutput_level * 4)
               
               aj_dicttype = "[]"
               For Each aj_label In objDict.Item(aj_item).Keys
                   If Not aj_IsInt(aj_label) Then aj_dicttype = "{}"
               Next
               If aj_IsInt(aj_item) Then
                  GetDict = GetDict & (Left(aj_dicttype,1) & Chr(13) & Chr(10))
               Else
                  GetDict = GetDict & ("""" & aj_JSONEncode(aj_item) & """" & ": " & Left(aj_dicttype,1) & Chr(13) & Chr(10))
               End If
               JSONoutput_level = JSONoutput_level + 1
               
               aj_keyvals = objDict.Keys
               GetDict = GetDict & (GetSubDict(objDict.Item(aj_item)) & Space(JSONoutput_level * 4) & Right(aj_dicttype,1) & aj_InlineIf(aj_item = aj_keyvals(objDict.Count - 1),"" , ",") & Chr(13) & Chr(10))
            Case Else
               aj_keyvals =  objDict.Keys
               GetDict = GetDict & (Space(JSONoutput_level * 4) & aj_InlineIf(aj_IsInt(aj_item), "", """" & aj_JSONEncode(aj_item) & """: ") & WriteValue(objDict.Item(aj_item)) & aj_InlineIf(aj_item = aj_keyvals(objDict.Count - 1),"" , ",") & Chr(13) & Chr(10))
         End Select
      Next
   End Function

   Private Function aj_IsInt(val)
      aj_IsInt = (TypeName(val) = "Integer" Or TypeName(val) = "Long")
   End Function

   Private Function GetSubDict(objSubDict)
      GetSubDict = GetDict(objSubDict)
      JSONoutput_level= JSONoutput_level -1
   End Function

   Private Function WriteValue(ByVal val)
      Select Case TypeName(val)
         Case "Double", "Integer", "Long": WriteValue = val
         Case "Null"                  : WriteValue = "null"
         Case "Boolean"               : WriteValue = aj_InlineIf(val, "true", "false")
         Case Else                  : WriteValue = """" & aj_JSONEncode(val) & """"
      End Select
   End Function

   Private Function aj_JSONEncode(ByVal val)
      val = Replace(val, "\", "\\")
      val = Replace(val, """", "\""")
      'val = Replace(val, "/", "\/")
      val = Replace(val, Chr(8), "\b")
      val = Replace(val, Chr(12), "\f")
      val = Replace(val, Chr(10), "\n")
      val = Replace(val, Chr(13), "\r")
      val = Replace(val, Chr(9), "\t")
      aj_JSONEncode = Trim(val)
   End Function

   Private Function aj_JSONDecode(ByVal val)
      val = Replace(val, "\""", """")
      val = Replace(val, "\\", "\")
      val = Replace(val, "\/", "/")
      val = Replace(val, "\b", Chr(8))
      val = Replace(val, "\f", Chr(12))
      val = Replace(val, "\n", Chr(10))
      val = Replace(val, "\r", Chr(13))
      val = Replace(val, "\t", Chr(9))
      aj_JSONDecode = Trim(val)
   End Function

   Private Function aj_InlineIf(condition, returntrue, returnfalse)
      If condition Then aj_InlineIf = returntrue Else aj_InlineIf = returnfalse
   End Function

   Private Function aj_Strip(ByVal val, stripper)
      If Left(val, 1) = stripper Then val = Mid(val, 2)
      If Right(val, 1) = stripper Then val = Left(val, Len(val) - 1)
      aj_Strip = val
   End Function

   Private Function aj_MultilineTrim(TextData)
      aj_MultilineTrim = aj_RegExp.Replace(TextData, "$1")
   End Function

   private function aj_Trim(val)
      aj_Trim = Trim(val)
      Do While Left(aj_Trim, 1) = Chr(9) : aj_Trim = Mid(aj_Trim, 2) : Loop
      Do While Right(aj_Trim, 1) = Chr(9) : aj_Trim = Left(aj_Trim, Len(aj_Trim) - 1) : Loop
      aj_Trim = Trim(aj_Trim)
   end function
End Class

Re: afvalwijzer script

PostPosted: Wed Aug 12, 2015 1:01 pm
by raymonvdm
Als ik dit script inderdaad uitvoer krijg ik een overzicht van alle ophaal data, mijn locatie is dus inderdaad geschikt :-)